# Maintainer: Blake Romero <blake@blkrom.com>
pkgname=swayimg-git
pkgver=4.5.r9.g59f5d67
pkgrel=1
pkgdesc="A lightweight image viewer for Wayland"
arch=('x86_64')
url="https://github.com/artemsen/swayimg"
license=('MIT')
groups=()
depends=(
'libjpeg-turbo'
'libjxl'
'libpng'
'giflib'
'librsvg'
'libwebp'
'libheif'
'libavif'
'libtiff'
'openexr'
'libexif'

'bash-completion'
'glibc'

'wayland'
'wayland-protocols'
'json-c'
'libxkbcommon'
'fontconfig'
'freetype2'

# 'hicolor-icon-theme'
# 'cairo'
# 'glib2'
)
makedepends=('git' 'meson' 'ninja')
optdepends=()
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}" "${pkgname}")
replaces=()
backup=()
options=()
install=
source=("${pkgname%-*}::git+${url}")
noextract=()
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname%-*}"
  git describe --long --abbrev=7 --tags \
    | sed 's/\([^-]*-g\)/r\1/; s/-/./g; s/^v//'
}

build() {
  cd "$srcdir/${pkgname%-*}"
  meson setup build --prefix=/usr
  ninja -C build
}

package() {
  cd "$srcdir/${pkgname%-*}"
  DESTDIR="$pkgdir/" ninja -C build install
  install -Dm 644 LICENSE \
    "$pkgdir/usr/share/licenses/${pkgname%-*}/LICENSE"
}