# Maintainer: Blake Romero <blake@blkrom.com>
pkgname=yambar-git
pkgver=1.11.0.r41.gb15714b
pkgrel=1
pkgdesc="Simplistic and highly configurable status paanel for Wayland"
arch=('x86_64')
url="https://codeberg.org/dnkl/yambar"
license=('MIT')
groups=()
depends=('wayland' 'wayland-protocols' 'pixman' 'glibc' 'json-c' 'alsa-lib'
         'libyaml' 'libpulse' 'libpipewire' 'libmpdclient' 'libudev' 'fontconfig'
         'harfbuzz' 'freetype2' 'xcb-util' 'xcb-util-cursor')
makedepends=('git' 'meson' 'ninja' 'scdoc' 'tllist')
optdepends=()
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}" "${pkgname}")
replaces=()
backup=()
options=()
install=
source=("${pkgname%-*}::git+${url}")
noextract=()
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname%-*}"
  git describe --long --abbrev=7 | sed 's/\([^-]*-g\)/r\1/; s/-/./g; s/^v//'
}

prepare() {
  mkdir -p "$srcdir/${pkgname%-*}/build"
}

build() {
  cd "$srcdir/${pkgname%-*}/build"
  meson setup \
    --prefix=/usr --buildtype=release -Db_lto=true \
    -Dbackend-x11=disabled -Dbackend-wayland=enabled \
    ..
  ninja
}

check() {
  cd "$srcdir/${pkgname%-*}/build"
  ninja test
}

package() {
  cd "$srcdir/${pkgname%-*}/build"
  DESTDIR="$pkgdir/" ninja install
  install -Dm 644 \
    ../LICENSE "$pkgdir/usr/share/licenses/${pkgname%-*}/LICENSE"
}