1 files changed, 58 insertions, 0 deletions
diff --git a/foot/PKGBUILD b/foot/PKGBUILD
new file mode 100644
index 0000000..bb33755
--- /dev/null
+++ b/foot/PKGBUILD
@@ -0,0 +1,58 @@
+# Maintainer: Blake Romero <blake@blkrom.com>
+pkgname=foot-git
+pkgver=1.19.0.r8.gd3cd4ad
+pkgrel=1
+pkgdesc="A fast, lightweight, and minimalistic Wayland terminal emulator"
+arch=('x86_64')
+url="https://codeberg.org/dnkl/foot"
+license=('MIT')
+groups=()
+depends=('fontconfig' 'pixman' 'wayland' 'libxkbcommon' 'glibc'
+         'hicolor-icon-theme' 'harfbuzz' 'freetype2')
+makedepends=('git' 'meson' 'ninja' 'wayland-protocols' 'ncurses'
+             'scdoc' 'tllist')
+optdepends=('libutf8proc: grapheme clustering'
+            'libutempter: utmp logging'
+            'libnotify: notifications'
+            'xdg-utils: URI launching'
+            'bash-completion: bash completions')
+provides=("${pkgname%-*}")
+conflicts=("${pkgname%-*}" "${pkgname}")
+replaces=()
+backup=()
+options=()
+install=
+source=("${pkgname%-*}::git+${url}")
+noextract=()
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/${pkgname%-*}"
+  git describe --long --abbrev=7 | sed 's/\([^-]*-g\)/r\1/; s/-/./g; s/^v//'
+}
+
+prepare() {
+  mkdir -p "$srcdir/${pkgname%-*}/build"
+  export CFLAGS="$CFLAGS -O3"
+}
+
+build() {
+  cd "$srcdir/${pkgname%-*}/build"
+  meson setup \
+    --prefix=/usr --buildtype=release -Db_lto=true \
+    -Dterminfo=disabled \
+    ..
+  ninja
+}
+
+check() {
+  cd "$srcdir/${pkgname%-*}/build"
+  ninja test
+}
+
+package() {
+  cd "$srcdir/${pkgname%-*}/build"
+  DESTDIR="$pkgdir/" ninja install
+  install -Dm 644 \
+    ../LICENSE "$pkgdir/usr/share/licenses/${pkgname%-*}/LICENSE"
+}