1 files changed, 35 insertions, 0 deletions
diff --git a/lavalauncher/PKGBUILD b/lavalauncher/PKGBUILD
new file mode 100644
index 0000000..f3d3a13
--- /dev/null
+++ b/lavalauncher/PKGBUILD
@@ -0,0 +1,35 @@
+# Maintainer: Blake Romero <blake@blkrom.com>
+pkgname=lavalauncher-git
+pkgver=2.1.1.r0.gda17d8a
+pkgrel=1
+pkgdesc='A simple launcher panel for Wayland'
+arch=('x86_64')
+url='https://git.sr.ht/~leon_plickat/lavalauncher'
+license=('GPL3')
+depends=('wayland' 'wayland-protocols' 'libxkbcommon' 'cairo' 'librsvg')
+makedepends=('git' 'meson' 'scdoc')
+provides=("${pkgname%-*}")
+conflicts=("${pkgname%-*}" "${pkgname}")
+source=("${pkgname%-*}::git+${url}")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "${pkgname%-*}"
+  git describe --long --abbrev=7 | sed 's/\([^-]*-g\)/r\1/; s/-/./g; s/^v//'
+}
+
+build() {
+    cd "${pkgname%-*}"
+    meson setup \
+        --prefix=/usr \
+        --buildtype release \
+        build
+    ninja -C build
+}
+
+package() {
+    cd "${pkgname%-*}"
+    DESTDIR="$pkgdir" ninja -C build install
+    install -D -m 644 LICENSE "$pkgdir"/usr/share/licenses/"${pkgname%-*}"/LICENSE
+    install -D -m 644 README.md "$pkgdir"/usr/share/doc/"${pkgname%-*}"/README.md
+}